***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Oct 08, 2024                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5594-AU     drain  gate  source
Lg     gate   g1   2.2n
Ld     drain  d1   100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     0.83
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=52.5  VTO=3.80  LEVEL=3  VMAX=1.2e5  ETA=0.006  gamma=1.6 nfs=3.210e+11)
Rd     d1    d2    35m TC=6.8m,18u
Dbd     s2    d2    Dbt
.MODEL     Dbt    D(BV=155     TBV1=6.920e-4  TBV2=-2.300e-8 CJO=5.194e-10  M=1.507  VJ=4.827e+1)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=7.798e-15  N=8.658e-1  RS=0.04u  EG=1.160  TT=30n  ikf=1.315)
Rdiode  d1  21    2.484e-3 TC=2.2m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   4.380e-10
.MODEL     DGD    D(M=1.175   CJO=4.380e-10   VJ=4.438)
Rpar      b    d2   1Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    6.900e-10
.ENDS
*$
